Verwenden von SSIS - Amazon Relational Database Service
Festlegen von Datenbankverbindungs-Managern für SSIS-ProjekteErstellen eines SSIS-ProxysPlanen eines SSIS-Pakets mit SQL Server-AgentWiderrufen des SSIS-Zugriffs vom Proxy

Die vorliegende Übersetzung wurde maschinell erstellt. Im Falle eines Konflikts oder eines Widerspruchs zwischen dieser übersetzten Fassung und der englischen Fassung (einschließlich infolge von Verzögerungen bei der Übersetzung) ist die englische Fassung maßgeblich.

Verwenden von SSIS

Nachdem Sie das SSIS-Projekt im SSIS-Katalog bereitgestellt haben, können Sie Pakete direkt aus SSMS ausführen oder mithilfe des SQL Server-Agents planen. Sie müssen eine Windows-authentifizierte Anmeldung für die Ausführung von SSIS-Paketen verwenden. Weitere Informationen finden Sie unter Einrichten eines Windows-authentifizierten Benutzers für SSIS.

Festlegen von Datenbankverbindungs-Managern für SSIS-Projekte

Bei Einsatz eines Verbindungs-Managers können Sie die folgenden Authentifizierungstypen verwenden:

  • Für lokale Datenbankverbindungen mit AWS Managed Active Directory können Sie die SQL-Authentifizierung oder die Windows-Authentifizierung verwenden. Verwenden Sie für die Windows-Authentifizierung DB_instance_name.fully_qualified_domain_name als Servername der Verbindungszeichenfolge.

    Ein Beispiel ist myssisinstance.corp-ad.example.com, wobei myssisinstance der Name der DB-Instance und corp-ad.example.com der vollqualifizierte Domänenname ist.

  • Verwenden Sie für Remoteverbindungen immer die SQL-Authentifizierung.

  • Für lokale Datenbankverbindungen mit selbstverwaltetem Active Directory können Sie die SQL-Authentifizierung oder die Windows-Authentifizierung verwenden. Verwenden Sie für die Windows-Authentifizierung . oder LocalHost als Servername der Verbindungszeichenfolge.

Erstellen eines SSIS-Proxys

Um SSIS-Pakete mit SQL Server-Agent planen zu können, erstellen Sie SSIS-Anmeldeinformationen und einen SSIS-Proxy. Führen Sie diese Prozeduren als Windows-authentifizierter Benutzer aus.

So erstellen Sie die SSIS-Anmeldeinformationen

  • Erstellen Sie die Anmeldeinformationen für den Proxy. Dazu können Sie SSMS oder die folgende SQL-Anweisung verwenden.

    USE [master]
GO
CREATE CREDENTIAL [SSIS_Credential] WITH IDENTITY = N'mydomain\user_name', SECRET = N'mysecret'
GO
    Anmerkung

    IDENTITY muss eine domänenauthentifizierter Anmeldung sein. Ersetzen Sie mysecret durch das Passwort für die domänenauthentifizierte Anmeldung.

    Wandeln Sie bei jedem Wechsel des primären SSISDB-Hosts die SSIS-Proxy-Anmeldeinformationen ab, damit der neue Host darauf zugreifen kann.

So erstellen Sie den SSIS-Proxy

  1. Verwenden Sie die folgende SQL-Anweisung, um den Proxy zu erstellen.

    USE [msdb]
GO
EXEC msdb.dbo.sp_add_proxy @proxy_name=N'SSIS_Proxy',@credential_name=N'SSIS_Credential',@description=N''
GO

  2. Verwenden Sie die folgende SQL-Anweisung, um anderen Benutzern den Zugriff auf den Proxy zu gewähren.

    USE [msdb]
GO
EXEC msdb.dbo.sp_grant_login_to_proxy @proxy_name=N'SSIS_Proxy',@login_name=N'mydomain\user_name'
GO

  3. Verwenden Sie die folgende SQL-Anweisung, um dem SSIS-Subsystem Zugriff auf den Proxy zu gewähren.

    USE [msdb]
GO
EXEC msdb.dbo.rds_sqlagent_proxy @task_type='GRANT_SUBSYSTEM_ACCESS',@proxy_name='SSIS_Proxy',@proxy_subsystem='SSIS'
GO
So zeigen Sie den Proxy und die Berechtigungserteilungen für den Proxy an

  1. Verwenden Sie die folgende SQL-Anweisung, um die Empfänger des Proxys anzuzeigen.

    USE [msdb]
GO
EXEC sp_help_proxy
GO

  2. Verwenden Sie die folgende SQL-Anweisung, um die Subsystemzuweisungen anzuzeigen.

    USE [msdb]
GO
EXEC msdb.dbo.sp_enum_proxy_for_subsystem
GO

Planen eines SSIS-Pakets mit SQL Server-Agent

Nachdem Sie die Anmeldeinformationen und den Proxy erstellt und SSIS-Zugriff auf den Proxy gewährt haben, können Sie einen SQL Server-Agent-Auftrag erstellen, um das SSIS-Paket zu planen.

So planen Sie das SSIS-Paket

  • Sie können SSMS oder T-SQL zum Erstellen des SQL Server-Agent-Auftrags verwenden. Im folgenden Beispiel wird T-SQL verwendet.

    USE [msdb]
GO
DECLARE @jobId BINARY(16)
EXEC msdb.dbo.sp_add_job @job_name=N'MYSSISJob',
@enabled=1,
@notify_level_eventlog=0,
@notify_level_email=2,
@notify_level_page=2,
@delete_level=0,
@category_name=N'[Uncategorized (Local)]',
@job_id = @jobId OUTPUT
GO
EXEC msdb.dbo.sp_add_jobserver @job_name=N'MYSSISJob',@server_name=N'(local)'
GO
EXEC msdb.dbo.sp_add_jobstep @job_name=N'MYSSISJob',@step_name=N'ExecuteSSISPackage',
@step_id=1,
@cmdexec_success_code=0,
@on_success_action=1,
@on_fail_action=2,
@retry_attempts=0,
@retry_interval=0,
@os_run_priority=0,
@subsystem=N'SSIS',
@command=N'/ISSERVER "\"\SSISDB\MySSISFolder\MySSISProject\MySSISPackage.dtsx\"" /SERVER "\"my-rds-ssis-instance.corp-ad.company.com/\"" 
/Par "\"$ServerOption::LOGGING_LEVEL(Int16)\"";1 /Par "\"$ServerOption::SYNCHRONIZED(Boolean)\"";True /CALLERINFO SQLAGENT /REPORTING E',
@database_name=N'master',
@flags=0,
@proxy_name=N'SSIS_Proxy'
GO

Widerrufen des SSIS-Zugriffs vom Proxy

Sie können den Zugriff auf das SSIS-Subsystem widerrufen und den SSIS-Proxy mithilfe der folgenden gespeicherten Prozeduren löschen.

So entziehen Sie den Zugriff und löschen den Proxy

  1. Widerrufen des Teilsystemzugriffs.

    USE [msdb]
GO
EXEC msdb.dbo.rds_sqlagent_proxy @task_type='REVOKE_SUBSYSTEM_ACCESS',@proxy_name='SSIS_Proxy',@proxy_subsystem='SSIS'
GO

  2. Widerrufen Sie die für den erteilten Berechtigungen Proxy.

    USE [msdb]
GO
EXEC msdb.dbo.sp_revoke_login_from_proxy @proxy_name=N'SSIS_Proxy',@name=N'mydomain\user_name'
GO

  3. Löschen Sie den Proxy.

    USE [msdb]
GO
EXEC dbo.sp_delete_proxy @proxy_name = N'SSIS_Proxy'
GO