使用 Oracle Data Pump 將內部部署 Oracle 資料庫遷移至 Amazon RDS for Oracle

建立儲存貯體。

若要建立 S3 儲存貯體，請遵循 AWS 文件中的指示。

設定 IAM 許可。

若要設定許可，請遵循 AWS 文件中的指示。

建立目標 Amazon RDS for Oracle 資料庫執行個體。

若要建立 Amazon RDS for Oracle 執行個體，請遵循 AWS 文件中的指示。

將角色與資料庫執行個體建立關聯。

若要將角色與執行個體建立關聯，請遵循 AWS 文件中的指示。

建立使用者。

從 Oracle SQL Developer 或 SQL*Plus 連線至目標 Amazon RDS for Oracle 資料庫，並執行下列 SQL 命令來建立要匯入結構描述的使用者。

create user SAMPLE_SCHEMA identified by <PASSWORD>;
grant create session, resource to <USER NAME>;
alter user <USER NAME> quota 100M on users;

建立資料傾印檔案。

若要在 sample.dmpDATA_PUMP_DIR目錄中建立名為 的傾印檔案以匯出SAMPLE_SCHEMA使用者，請使用下列指令碼。

DECLARE
    hdnl NUMBER;
BEGIN
    hdnl := dbms_datapump.open(operation => 'EXPORT', 
                                job_mode => 'SCHEMA', 
                                job_name => NULL);

    dbms_datapump.add_file( handle => hdnl, 
                            filename => 'sample.dmp', 
                            directory => 'DATA_PUMP_DIR', 
                            filetype => dbms_datapump.ku$_file_type_dump_file);

    dbms_datapump.add_file(handle => hdnl, 
                            filename => 'export.log', 
                            directory => 'DATA_PUMP_DIR', 
                            filetype => dbms_datapump.ku$_file_type_log_file);

    dbms_datapump.metadata_filter(hdnl, 'SCHEMA_EXPR', 'IN (''SAMPLE_SCHEMA'')');  

    dbms_datapump.start_job(hdnl);
END;
/

檢閱本機DATA_PUMP_DIR目錄中export.log的檔案，以檢閱匯出詳細資訊。

將資料傾印檔案從來源上傳至 S3 儲存貯體。

使用 AWS CLI，執行下列命令。

aws s3 cp sample.dmp s3://<bucket_created_epic_1>/

將資料傾印檔案下載至 Amazon RDS

若要將傾印檔案sample.dmp從 S3 儲存貯體複製到 Amazon RDS for Oracle 資料庫，請執行下列 SQL 命令。在此範例中，sample.dmp檔案會從 S3 儲存貯體下載my-s3-integration1至 Oracle 目錄 DATA_PUMP_DIR。請確定已將足夠的磁碟空間配置給 RDS 執行個體，以容納資料庫和匯出檔案。

-- If you want to download all the files in the S3 bucket remove the p_s3_prefix line.

SELECT rdsadmin.rdsadmin_s3_tasks.download_from_s3(
      p_bucket_name    =>  'my-s3-integration',    
      p_s3_prefix => 'sample.dmp',
      p_directory_name =>  'DATA_PUMP_DIR') 
   AS TASK_ID FROM DUAL;

先前的命令會輸出任務 ID。若要檢閱任務 ID 中的資料來檢閱下載狀態，請執行下列命令。

SELECT text FROM table(rdsadmin.rds_file_util.read_text_file('BDUMP','dbtask-<task_id>.log'));

若要查看 DATA_PUMP_DIR目錄中的檔案，請執行下列命令。

SELECT filename,type,filesize/1024/1024 size_megs,to_char(mtime,'DD-MON-YY HH24:MI:SS') timestamp
FROM TABLE(rdsadmin.rds_file_util.listdir(p_directory => upper('DATA_PUMP_DIR'))) order by 4;

將結構描述和資料還原至 Amazon RDS。

若要將傾印檔案匯入sample_schema資料庫結構描述，請從 SQL Developer 或 SQL*Plus 執行下列 SQL 命令。

DECLARE
hdnl NUMBER;
BEGIN

hdnl := DBMS_DATAPUMP.OPEN( operation => 'IMPORT', job_mode => 'SCHEMA', job_name=>null);

DBMS_DATAPUMP.ADD_FILE( handle => hdnl, filename => 'sample.dmp', directory => 'DATA_PUMP_DIR', filetype => dbms_datapump.ku$_file_type_dump_file);

DBMS_DATAPUMP.ADD_FILE( handle    => hdnl, filename  => 'import.log', directory => 'DATA_PUMP_DIR', filetype  => dbms_datapump.ku$_file_type_log_file);

DBMS_DATAPUMP.METADATA_FILTER(hdnl,'SCHEMA_EXPR','IN (''SAMPLE_SCHEMA'')');

DBMS_DATAPUMP.START_JOB(hdnl);

END;
/

若要從匯入查看日誌檔案，請執行下列命令。

SELECT text FROM table(rdsadmin.rds_file_util.read_text_file('DATA_PUMP_DIR','import.log'));

列出並清除匯出檔案。

列出並移除 DATA_PUMP_DIR目錄中的匯出檔案，執行下列命令。

-- List the files
SELECT filename,type,filesize/1024/1024 size_megs,to_char(mtime,'DD-MON-YY HH24:MI:SS') timestamp FROM TABLE(rdsadmin.rds_file_util.listdir(p_directory => upper('DATA_PUMP_DIR'))) order by 4;

-- Remove the files
EXEC UTL_FILE.FREMOVE('DATA_PUMP_DIR','sample.dmp');
EXEC UTL_FILE.FREMOVE('DATA_PUMP_DIR','import.log');