Oracle Data Pump を使用してオンプレミスの Oracle データベースを Amazon RDS for Oracle に移行する

バケットを作成します。

S3 バケットを作成するには、AWS のドキュメントの手順に従います。

IAM 許可を設定します。

権限を設定するには、「AWS ドキュメント」の指示に従ってください。

ターゲットの Amazon RDS for Oracle DB インスタンスを停止します。

Amazon RDS for Oracle インスタンスを作成するには、「AWS ドキュメント」の指示に従ってください。

ロールを DB インスタンスに関連付けます。

ロールをインスタンスに関連付けるには、「AWS ドキュメント」の指示に従ってください。

ユーザーを作成します。

Oracle SQL Developer または SQL*Plus からターゲットの Amazon RDS for Oracle データベースに接続し、次の SQL コマンドを実行して、スキーマをインポートするユーザーを作成します。

create user SAMPLE_SCHEMA identified by <PASSWORD>;
grant create session, resource to <USER NAME>;
alter user <USER NAME> quota 100M on users;

データダンプファイルを作成する。

DATA_PUMP_DIR ディレクトリに sample.dmp というダンプファイルを作成して SAMPLE_SCHEMA ユーザーをエクスポートするには、次のスクリプトを使用します。

DECLARE
    hdnl NUMBER;
BEGIN
    hdnl := dbms_datapump.open(operation => 'EXPORT', 
                                job_mode => 'SCHEMA', 
                                job_name => NULL);

    dbms_datapump.add_file( handle => hdnl, 
                            filename => 'sample.dmp', 
                            directory => 'DATA_PUMP_DIR', 
                            filetype => dbms_datapump.ku$_file_type_dump_file);

    dbms_datapump.add_file(handle => hdnl, 
                            filename => 'export.log', 
                            directory => 'DATA_PUMP_DIR', 
                            filetype => dbms_datapump.ku$_file_type_log_file);

    dbms_datapump.metadata_filter(hdnl, 'SCHEMA_EXPR', 'IN (''SAMPLE_SCHEMA'')');  

    dbms_datapump.start_job(hdnl);
END;
/

ローカル DATA_PUMP_DIR ディレクトリにある export.log ファイルを参照して、エクスポートの詳細を確認します。

データダンプファイルをソースから S3 バケットにアップロードします。

AWS CLI を使用して、次のコマンドを実行します。

aws s3 cp sample.dmp s3://<bucket_created_epic_1>/

データダンプファイルを Amazon RDS にダウンロードします。

ダンプファイル sample.dmp を S3 バケットから Amazon RDS for Oracle データベースにコピーするには、次の SQL コマンドを実行します。この例では、sample.dmp ファイルが S3 バケット my-s3-integration1 から Oracle ディレクトリ DATA_PUMP_DIR にダウンロードされます。RDS インスタンスには、データベースとエクスポートファイルの両方を収容するのに十分なディスクスペースが割り当てられていることを確認してください。

-- If you want to download all the files in the S3 bucket remove the p_s3_prefix line.

SELECT rdsadmin.rdsadmin_s3_tasks.download_from_s3(
      p_bucket_name    =>  'my-s3-integration',    
      p_s3_prefix => 'sample.dmp',
      p_directory_name =>  'DATA_PUMP_DIR') 
   AS TASK_ID FROM DUAL;

前のコマンドはタスク ID を出力します。タスク ID のデータを確認してダウンロードのステータスを確認するには、以下のコマンドを実行します。

SELECT text FROM table(rdsadmin.rds_file_util.read_text_file('BDUMP','dbtask-<task_id>.log'));

DATA_PUMP_DIR ディレクトリ内のファイルを確認するには、次のコマンドを実行します。

SELECT filename,type,filesize/1024/1024 size_megs,to_char(mtime,'DD-MON-YY HH24:MI:SS') timestamp
FROM TABLE(rdsadmin.rds_file_util.listdir(p_directory => upper('DATA_PUMP_DIR'))) order by 4;

スキーマとデータを Amazon RDS に復元します。

ダンプファイルを sample_schema データベーススキーマにインポートするには、SQL Developer または SQL*Plus から次の SQL コマンドを実行します。

DECLARE
hdnl NUMBER;
BEGIN

hdnl := DBMS_DATAPUMP.OPEN( operation => 'IMPORT', job_mode => 'SCHEMA', job_name=>null);

DBMS_DATAPUMP.ADD_FILE( handle => hdnl, filename => 'sample.dmp', directory => 'DATA_PUMP_DIR', filetype => dbms_datapump.ku$_file_type_dump_file);

DBMS_DATAPUMP.ADD_FILE( handle    => hdnl, filename  => 'import.log', directory => 'DATA_PUMP_DIR', filetype  => dbms_datapump.ku$_file_type_log_file);

DBMS_DATAPUMP.METADATA_FILTER(hdnl,'SCHEMA_EXPR','IN (''SAMPLE_SCHEMA'')');

DBMS_DATAPUMP.START_JOB(hdnl);

END;
/

インポートのログファイルを表示するには、以下のコマンドを実行します。

SELECT text FROM table(rdsadmin.rds_file_util.read_text_file('DATA_PUMP_DIR','import.log'));

エクスポートファイルを一覧表示してクリーンアップします。

DATA_PUMP_DIR ディレクトリのエクスポートファイルを一覧表示して削除し、次のコマンドを実行します。

-- List the files
SELECT filename,type,filesize/1024/1024 size_megs,to_char(mtime,'DD-MON-YY HH24:MI:SS') timestamp FROM TABLE(rdsadmin.rds_file_util.listdir(p_directory => upper('DATA_PUMP_DIR'))) order by 4;

-- Remove the files
EXEC UTL_FILE.FREMOVE('DATA_PUMP_DIR','sample.dmp');
EXEC UTL_FILE.FREMOVE('DATA_PUMP_DIR','import.log');