Le traduzioni sono generate tramite traduzione automatica. In caso di conflitto tra il contenuto di una traduzione e la versione originale in Inglese, quest'ultima prevarrà.

# Monitora l'utilizzo dello storage degli indici
<a name="index-usage-monitoring"></a>

I log di utilizzo degli indici forniscono visibilità su come viene utilizzato lo storage degli indici Amazon Quick nelle knowledge base e negli spazi, compresi i caricamenti di file. Puoi utilizzare questi log per tenere traccia delle tendenze di crescita, identificare le fonti più importanti, rilevare picchi imprevisti e pianificare la capacità.

Prima di interrogare i dati di utilizzo dell'indice, è necessario configurare `INDEX_USAGE_LOGS` la consegna. Per istruzioni sulla configurazione della consegna, consulta[Monitoraggio dell'utilizzo di Amazon Quick tramite CloudWatch log](monitoring-quicksuite-chat-feedback-cloudwatch.md).

## Schema di registro
<a name="index-usage-monitoring-schema"></a>

Ogni evento del registro di utilizzo dell'indice include i campi comuni condivisi tra tutti i tipi di Amazon Quick log`resource_arn`, ad esempio`event_timestamp`,`log_type`,`account_id`, e`user_arn`. L'evento include anche i seguenti campi specifici dell'indice:


**Campi del registro di utilizzo dell'indice**  

| Campo | Tipo | Description | 
| --- | --- | --- | 
| consumed\_index\_size | Numero intero | Dimensione totale (in byte) consumata dall'intero indice. Questo è il totale autorevole. | 
| source\_type | Stringa | SPACE o KB. | 
| source\_name | Stringa | Visualizza il nome dello spazio o della knowledge base. | 
| source\_arn | Stringa | ARN completo della fonte. | 
| consumed\_source\_size | Numero intero | Dimensione (in byte) consumata da questa singola fonte. | 
| consumed\_source\_doc\_count | Numero intero | Numero di documenti in questa fonte. | 

**Nota**  
Gli eventi vengono pubblicati per fonte sulle modifiche. Non tutte le fonti emettono eventi ogni giorno. Per ricostruire lo stato corrente, usa l'evento più recente per. `source_arn`

## CloudWatch Registra le interrogazioni di Insights
<a name="index-usage-monitoring-queries"></a>

Le seguenti query di CloudWatch Logs Insights consentono di analizzare i dati sull'utilizzo dell'indice. Tutte le query utilizzano lo schema `stats latest(field) by source_arn` per ottenere lo stato più recente per fonte. Le interrogazioni vengono quindi aggregate secondo necessità. {{YOUR\_LOG\_GROUP}}Sostituiscilo con il nome del tuo gruppo di log.

### Dimensioni per tipo di fonte (basi di conoscenza rispetto a Spaces)
<a name="index-usage-query-kb-vs-spaces"></a>

Mostra la ripartizione totale delle dimensioni tra knowledge base e Spaces.

```
fields @timestamp, source_type, source_arn, consumed_source_size
| stats latest(consumed_source_size) as latest_size, latest(source_type) as type by source_arn
| stats sum(latest_size) as total_size by type
```

### Dimensione totale dell'indice nel tempo
<a name="index-usage-query-total-over-time"></a>

Mostra l'andamento delle dimensioni dell'indice utilizzando il `consumed_index_size` campo.

```
fields @timestamp, consumed_index_size
| stats latest(consumed_index_size) as total_index_size by bin(1d) as day
| sort day asc
```

### Principali basi di conoscenza per dimensione
<a name="index-usage-query-top-kb"></a>

Mostra le 20 principali basi di conoscenza classificate per dimensione.

```
fields @timestamp, source_type, source_arn, source_name, consumed_source_size
| filter source_type = "KB"
| stats latest(consumed_source_size) as latest_size, latest(source_name) as name by source_arn
| sort latest_size desc
| limit 20
```

### Spazi principali per dimensione
<a name="index-usage-query-top-spaces"></a>

Mostra i primi 20 spazi classificati per dimensione.

```
fields @timestamp, source_type, source_arn, source_name, consumed_source_size
| filter source_type = "SPACE"
| stats latest(consumed_source_size) as latest_size, latest(source_name) as name by source_arn
| sort latest_size desc
| limit 20
```

### Tutti i dettagli delle fonti
<a name="index-usage-query-all-sources"></a>

Mostra lo stato più recente di ogni fonte con dimensioni, tipo, nome, numero di documenti e ora dell'ultimo aggiornamento.

```
fields @timestamp, source_type, source_name, consumed_source_size, consumed_source_doc_count, source_arn
| stats latest(consumed_source_size) as latest_size, latest(source_type) as type, latest(source_name) as name, latest(consumed_source_doc_count) as doc_count, latest(@timestamp) as last_updated by source_arn
| sort latest_size desc
| limit 100
```

### Principali utenti per dimensione totale
<a name="index-usage-query-top-users"></a>

Mostra i primi 20 utenti classificati in base alla dimensione totale della fonte in tutte le loro fonti.

```
fields @timestamp, user_arn, source_arn, consumed_source_size
| parse user_arn "*:user/*/*" as @prefix, @namespace, @username
| stats latest(consumed_source_size) as latest_size, latest(@username) as user by source_arn
| stats sum(latest_size) as total_size by user
| sort total_size desc
| limit 20
```

## Crea una dashboard CloudWatch
<a name="index-usage-monitoring-dashboard"></a>

Puoi creare una CloudWatch dashboard per visualizzare le metriche di utilizzo dell'indice. Utilizza la CloudWatch console per creare una dashboard e aggiungere i widget di Logs Insights utilizzando le query della sezione precedente.

1. Apri la [CloudWatch console](https://console.aws.amazon.com/cloudwatch).

1. Nel pannello di navigazione seleziona **Dashboards** (Pannelli di controllo).

1. Scegli **Crea dashboard** e inserisci un nome (ad esempio,). `IndexUsageMetrics`

1. Aggiungi widget utilizzando il tipo di widget **Logs.** Seleziona il gruppo di log sull'utilizzo dell'indice e incolla le query della sezione precedente.

**Suggerimento**  
Utilizza la visualizzazione del grafico a torta per la suddivisione del tipo di fonte. Utilizza il grafico a linee per visualizzare le dimensioni nel tempo. Usa il grafico a barre per le fonti principali. La visualizzazione della tabella funziona bene per l'interrogazione dettagliata di tutte le fonti.