Terjemahan disediakan oleh mesin penerjemah. Jika konten terjemahan yang diberikan bertentangan dengan versi bahasa Inggris aslinya, utamakan versi bahasa Inggris.

# Tentukan proyek Terraform
<a name="tutorial-deploy-terraform-define"></a>

Dalam tutorial ini, Anda akan mendefinisikan proyek Terraform.

1. Buat direktori yang disebut`my-pcluster-api`.

   Semua file yang Anda buat akan berada di dalam direktori ini.

1. Buat file `provider.tf` untuk mengkonfigurasi AWS penyedia.

   ```
   provider "aws" {
     region  = var.region
     profile = var.profile
   }
   ```

1. Buat file `main.tf` untuk menentukan sumber daya menggunakan ParallelCluster modul.

   ```
   module "parallelcluster_pcluster_api" {
     source = "aws-tf/parallelcluster/aws//modules/pcluster_api"
     version = "1.1.0"
   
     region                = var.region
     api_stack_name        = var.api_stack_name
     api_version           = var.api_version
   
     parameters = {
       EnableIamAdminAccess = "true"
     }
   }
   ```

1. Buat file `variables.tf` untuk menentukan variabel yang dapat disuntikkan untuk proyek ini.

   ```
   variable "region" {
     description = "The region the ParallelCluster API is deployed in."
     type        = string
     default     = "us-east-1"
   }
   
   variable "profile" {
     type        = string
     description = "The AWS profile used to deploy the clusters."
     default     = null
   }
   
   variable "api_stack_name" {
     type        = string
     description = "The name of the CloudFormation stack used to deploy the ParallelCluster API."
     default     = "ParallelCluster"
   }
   
   variable "api_version" {
     type        = string
     description = "The version of the ParallelCluster API."
   }
   ```

1. Buat file `terraform.tfvars` untuk menetapkan nilai arbitrer untuk variabel. 

   File di bawah ini menerapkan ParallelCluster API 3.11.1 dalam `us-east-1` menggunakan nama tumpukan. `MyParallelClusterAPI-3111` Anda akan dapat mereferensikan penerapan ParallelCluster API ini menggunakan nama tumpukannya. 
**catatan**  
`api_version`Penugasan dalam kode berikut dapat diganti dengan AWS ParallelCluster versi yang didukung. 

   ```
   region = "us-east-1"
   api_stack_name = "MyParallelClusterAPI-3111"
   api_version = "3.11.1"
   ```

1. Buat file `outputs.tf` untuk menentukan output yang dikembalikan oleh proyek ini.

   ```
   output "pcluster_api_stack_outputs" {
     value = module.parallelcluster_pcluster_api.stack_outputs
   }
   ```

   Direktori proyek adalah:

   ```
   my-pcluster-api
   ├── main.tf - Terraform entrypoint to define the resources using the ParallelCluster module.
   ├── outputs.tf - Defines the outputs returned by Terraform.
   ├── providers.tf - Configures the AWS provider.
   ├── terraform.tfvars - Set the arbitrary values for the variables, i.e. region, PCAPI version, PCAPI stack name
   └── variables.tf - Defines the variables, e.g. region, PCAPI version, PCAPI stack name.
   ```