Définir un projet Terraform - AWS ParallelCluster

Les traductions sont fournies par des outils de traduction automatique. En cas de conflit entre le contenu d'une traduction et celui de la version originale en anglais, la version anglaise prévaudra.

Définir un projet Terraform

Dans ce didacticiel, vous allez définir un projet Terraform.

  1. Créez un répertoire appelémy-pcluster-api.

    Tous les fichiers que vous créez se trouveront dans ce répertoire.

  2. Créez le fichier provider.tf pour configurer le AWS fournisseur.

    provider "aws" {
  region  = var.region
  profile = var.profile
}

  3. Créez le fichier main.tf pour définir les ressources à l'aide du ParallelCluster module.

    module "parallelcluster_pcluster_api" {
  source = "aws-tf/parallelcluster/aws//modules/pcluster_api"
  version = "1.1.0"

  region                = var.region
  api_stack_name        = var.api_stack_name
  api_version           = var.api_version

  parameters = {
    EnableIamAdminAccess = "true"
  }
}

  4. Créez le fichier variables.tf pour définir les variables qui peuvent être injectées pour ce projet.

    variable "region" {
  description = "The region the ParallelCluster API is deployed in."
  type        = string
  default     = "us-east-1"
}

variable "profile" {
  type        = string
  description = "The AWS profile used to deploy the clusters."
  default     = null
}

variable "api_stack_name" {
  type        = string
  description = "The name of the CloudFormation stack used to deploy the ParallelCluster API."
  default     = "ParallelCluster"
}

variable "api_version" {
  type        = string
  description = "The version of the ParallelCluster API."
}

  5. Créez le fichier terraform.tfvars pour définir des valeurs arbitraires pour les variables.

    Le fichier ci-dessous déploie une ParallelCluster API 3.11.1 en us-east-1 utilisant le nom de la pile. MyParallelClusterAPI-3111 Vous pourrez référencer ce déploiement d' ParallelCluster API à l'aide de son nom de pile.

    Note

    L'api_versionassignation dans le code suivant peut être remplacée par n'importe quelle AWS ParallelCluster version prise en charge. 

    region = "us-east-1"
api_stack_name = "MyParallelClusterAPI-3111"
api_version = "3.11.1"

  6. Créez le fichier outputs.tf pour définir les sorties renvoyées par ce projet.

    output "pcluster_api_stack_outputs" {
  value = module.parallelcluster_pcluster_api.stack_outputs
}

    Le répertoire du projet est le suivant :

    my-pcluster-api
├── main.tf - Terraform entrypoint to define the resources using the ParallelCluster module.
├── outputs.tf - Defines the outputs returned by Terraform.
├── providers.tf - Configures the AWS provider.
├── terraform.tfvars - Set the arbitrary values for the variables, i.e. region, PCAPI version, PCAPI stack name
└── variables.tf - Defines the variables, e.g. region, PCAPI version, PCAPI stack name.